 60000  REM  NadaNet Definitions for Applesoft
 60010  REM         MJM - 01/13/09
 60020 :
 60030 MX = 20: REM  Max machine ID
 60040  IF  PEEK (973) <  > 76 THEN  PRINT "NadaNet not loaded.": STOP 
 60050 SELF =  PEEK (972)
 60060  & IDTBL(ITBL): REM  ID table
 60070  RETURN 
 60080 :
 61000  REM  Take census of serving machines
 61010  & TIMEOUT(2): REM  Set short timeout
 61020 QC =  INT ( PEEK (33) / 13): REM  Number of columns
 61030 QL =  INT ((MX + QC - 1) / QC): REM  Number of lines
 61040  FOR I = 1 TO QL
 61050  FOR D = I TO MX STEP QL
 61060  IF D = SELF THEN J =  PEEK (975): GOTO 61110
 61070 A$ = "        "
 61080  &  PEEK #(D,975,1,512): REM  Machine type
 61090  IF  PEEK (1) THEN K = 0: GOTO 61150
 61100 J =  PEEK (512)
 61110  IF J = 184 THEN A$ = "CRATE   ":K = 2
 61120  IF J = 008 THEN A$ = "MSERVER ":K = 3
 61130  IF J = 145 THEN A$ = "PRODOS  ":K = 4
 61140  IF J = 141 THEN A$ = "DOS     ":K = 5
 61150  POKE ITBL + D,K: REM  Save type in IDTBL
 61160  IF D = SELF THEN A$ = "==SELF=="
 61170  IF D < 10 THEN  PRINT " ";
 61180  PRINT D":"A$"  ";
 61190  NEXT D
 61200  PRINT 
 61210  NEXT I
 61220  & TIMEOUT(): REM  Reset retrys
 61230  RETURN 
